pitot.pde

Go to the documentation of this file.

/***********************************************************
 * StoRC - Search to Rescue Craft
 * MEAM Senior Design 2011-2012
 * 
 * Authors:  Michael Posner (CIS, MEAM '12)
 * Timothy Hennelly (ESE '12)
 * Jacob Orloff (MEAM '12)
 * 
 * (some code from ArduPilot Mega project, found here:
 * http://code.google.com/p/ardupilot-mega/ )
 * 
 * Licensing:
 * 
 * This program is free software: you can redistribute it and/or modify 
 * it under the terms of the GNU General Public License as published by 
 * the Free Software Foundation, either version 3 of the License, or 
 * (at your option) any later version. 
 * 
 * This program is distributed in the hope that it will be useful, 
 * but WITHOUT ANY WARRANTY; without even the implied warranty of 
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the 
 * GNU General Public License for more details. 
 * 
 * You should have received a copy of the GNU General Public License 
 * along with this program. If not, see <http://www.gnu.org/licenses/>.
 * 
 ***********************************************************/

/**
 *  @file pitot.pde
 *  @brief Contains functions for reading pitot probe measurements
 *  @author Michael Posner (CIS, MEAM '12)
 *  @author Timothy Hennelly (ESE '12)
 *  @author Jacob Orloff (MEAM '12)
 *  
 *  Contains functions for reading and adjusting pressure 
 * measurements taken with the pitot probe.  Requires ADC functionality.
 */

/**
* Zero the airspeed measurement by storing the current pressure offset.
*/
void zero_pitot(void) {
  
  float differential = 0;  ///< differential between static and dynamic pressure values
  
  //this sequence helps account for the instability in the readings by reading a few measurements and averaging
  for(int i = 0; i < 10; i++){
    delay(20);
    //differential = (differential * .75) + ((float)adc.Ch(PITOT_CH) * .25);  //read in raw value from ADC
    differential += (float)adc.Ch(PITOT_CH);
    
  }
  differential /= 10.0f;
  
  pitot_pressure_offset = (differential/1000.0f - PITOT_OFFSET) * PITOT_RATIO;  //convert voltage reading to pressure in kPa

}


/**
 * Read airspeed from pitot probe, convert appropriately, and store
 */
void update_airspeed(void) {

  float differential = (float)adc.Ch(PITOT_CH);  //read in raw value from ADC (differential
  // between static and dynamic values)

  //Serial.print("Raw ADC: "); Serial.println(differential);

  float dynamic_pressure = ((differential/1000.0f - PITOT_OFFSET) * PITOT_RATIO) - pitot_pressure_offset;  //convert voltage reading to pressure in kPa
                                                      //shouldn't be negative (or else we're flying backwards)
  if(dynamic_pressure >= 0) {
    airspeed = sqrt(2.0f*dynamic_pressure*1000.0f/RHO);  // Pd = 1/2 * rho * V^2
  } else {
    airspeed = -1;  //some kind of error happened - maybe the wind was blowing into the side and decreasing the static pressure?
  }
}